在某次更新系统后电脑每次开机后WiFi功能就会消失，必须手动启动wlan autoconfig，启动类型是自动电脑开机仍需要手动启动服务才能启动，我试了网上的各种办法都不行，偶然看到一篇文章，用了上面的办法结果成功了。
1.在桌面创建一个txt文件，粘贴代码 保存 2.然后改文件后缀为bat 3. 添加开机自启，网上有许多办法，我这里用的是注册表方法：
代码：
@echo off
chcp 65001 >nul
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
:: 检查管理员权限
net session >nul 2>&1
if %errorlevel% neq 0 (
echo 请以管理员权限运行此脚本！
timeout /t 2 >nul
exit /b 1
)
echo 正在配置WLAN服务...
:: 设置服务为自动启动
sc config Wlansvc start=auto >nul 2>&1
if %errorlevel% neq 0 (
echo 配置服务启动类型失败！
timeout /t 2 >nul
exit /b 1
)
:: 检查服务是否已经在运行
sc query Wlansvc | find "RUNNING" >nul
if %errorlevel% equ 0 (
echo WLAN AutoConfig服务已经在运行中！
timeout /t 2 >nul
exit
)
:: 启动WLAN服务
echo 正在启动WLAN服务...
net start Wlansvc >nul 2>&1
if %errorlevel% equ 0 (
echo WLAN AutoConfig服务已成功启动！
timeout /t 2 >nul
) else (
echo 启动失败！可能原因：
echo 1. 无线网卡硬件未启用或驱动异常
echo 2. 服务已被第三方软件禁用
echo 3. 系统组件损坏
echo 请检查以上可能的原因后重试。
timeout /t 2 >nul
)
exit
注意：文件创建完之后先运行一下，看是否有用
按住Windows+R输入regedit
进入：计算机\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run 在右边空白处右键单击新建一个字符串值（S） 然后编辑一下内容，名称随意取个名字，数值数据是你创建的bat文件的路径
OK，大功告成！重启电脑后看看是否有用
参考原文链接：解决WLAN autoconfig设为自动后仍需要手动启动服务才能启动 (暴力启动完美解决篇 无视任何繁琐检查 只要是这个问题的前提下)_wlanautoconfig每次开机都要手动开启-CSDN博客